Περιεχόμενα

# COUNTIFS

Επιστρέφει τον αριθμό των κελιών που ικανοποιούν τα κριτήρια σε πολλαπλές περιοχές.

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.

### Σύνταξη

COUNTIFS(Περιοχή; Κριτήριο[; Περιοχή2; Κριτήριο2][; ... ; [Περιοχή127; Κριτήριο127]])

Περιοχή1 - Απαιτούμενο όρισμα. Είναι περιοχή κελιών, όνομα ονοματισμένης περιοχής, ή ετικέτα στήλης ή γραμμής, στην οποία εφαρμόζεται το αντίστοιχο κριτήριο.

Κριτήριο: Κριτήριο είναι μια μοναδική αναφορά κελιού, αριθμού, ή κειμένου. Χρησιμοποιείται σε συγκρίσεις με περιεχόμενα κελιού.

Μια αναφορά σε κενό κελί ερμηνεύεται ως η αριθμητική τιμή 0.

Μια σύμφωνη έκφραση μπορεί να είναι:

- Ένας αριθμός ή μια λογική τιμή. Ένα αντίστοιχο περιεχόμενο κελιού ισούται με τον αριθμό ή τη λογική τιμή.

- Μια τιμή που ξεκινά με έναν συγκριτικό (<, <=, =, >, >=, <>).

  Για =, εάν η τιμή είναι κενή αντιστοιχεί σε κενά κελιά.

  Για το <>, εάν η τιμή είναι κενή αντιστοιχεί σε μη κενά κελιά.

  Για το <>, εάν η τιμή δεν είναι κενή, αντιστοιχεί σε οποιοδήποτε περιεχόμενο κελιού εκτός από την τιμή, συμπεριλαμβανομένων των κενών κελιών.

  Σημείωση: "=0" δεν συμφωνεί με κενά κελιά.

  Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευτεί ως τύπος αριθμού ή ένας από τους υποτύπους του και η ιδιότητα Κριτήρια αναζήτησης = και <> πρέπει να ισχύουν για ολόκληρα κελιά έχει επιλεγεί, η σύγκριση γίνεται με ολόκληρο το περιεχόμενο του κελιού. Εάν είναι μη επιλεγμένο, η σύγκριση γίνεται με οποιοδήποτε υποτμήμα του πεδίου που αντιστοιχεί στα κριτήρια. Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευθεί ως τύπος Αριθμού ή ισχύει ένας από τους υποτύπους του.

- Άλλη τιμή κειμένου. Εάν η ιδιότητα Κριτήρια αναζήτησης = και <> πρέπει να ισχύει για ολόκληρα κελιά είναι αληθής , η σύγκριση γίνεται με το σύνολο των περιεχομένων του κελιού. Εάν είναι ψευδής, η σύγκριση γίνεται με οποιοδήποτε υποτμήμα του πεδίου που αντιστοιχεί στα κριτήρια. Η έκφραση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις ή χαρακτήρες υποκατάστασης (εάν είναι ενεργοποιημένη στις επιλογές υπολογισμού).

Περιοχή2 – Προαιρετικά. Η Περιοχή2 και όλα τα ακόλουθα σημαίνουν το ίδιο με την Περιοχή1.

Κριτήριο2 – Προαιρετικό. Κριτήριο2 και όλα τα παρακάτω σημαίνουν το ίδιο με το κριτήριο.

Η αναζήτηση υποστηρίζει χαρακτήρες Υποκατάστασης (μπαλαντέρ) ή κανονικές εκφράσεις. Με ενεργοποιημένες τις κανονικές εκφράσεις, μπορείτε να εισαγάγετε "all.*", για παράδειγμα, για να βρείτε την πρώτη θέση του "all" ακολουθούμενη από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε ένα κείμενο που είναι επίσης κανονική έκφραση, πρέπει είτε να προηγηθεί κάθε μεταχαρακτήρα ή τελεστή κανονικής έκφρασης με έναν χαρακτήρα "\" ή να περικλείσετε το κείμενο στο \Q...\E. Μπορείτε να ενεργοποιήσετε και να απενεργοποιήσετε την αυτόματη αξιολόγηση χαρακτήρων υποκατάστασης ή κανονικής έκφρασης στο LibreOffice - Προτιμήσεις Εργαλεία - Επιλογές - LibreOffice Υπολογισμός - Υπολογισμός .

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".

Τα Περιοχή, Περιοχή2, … και Κριτήριο, Κριτήριο2, … πρέπει να έχουν το ίδιο μέγεθος, αλλιώς η συνάρτηση επιστρέφει err:502 - Άκυρο όρισμα.

Η λογική σχέση μεταξύ κριτηρίων μπορεί να οριστεί ως λογικό AND (συνδυασμός). Με άλλα λόγια, εάν και μόνο εάν πληρούνται όλα τα κριτήρια, μια τιμή από το αντίστοιχο κελί της δεδομένης Περιοχής_συνάρτησης λαμβάνεται υπόψη στον υπολογισμό.

Η συνάρτηση μπορεί να έχει μέχρι 255 ορίσματα, που σημαίνει ότι μπορείτε να ορίσετε 127 περιοχές κριτηρίων και κριτήρια για αυτά.

Εάν το κελί περιέχει TRUE, θεωρείται ως 1, εάν ένα κελί περιέχει FALSE – ως 0 (μηδέν).

Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)

### Παραδείγματα

Θεωρήστε τον ακόλουθο πίνακα

| A | B | C
1 | Όνομα προϊόντος | Sales | Revenue
2 | μολύβι | 20 | 65
3 | στυλό | 35 | 85
4 | σημειωματάριο | 20 | 190
5 | βιβλίο | 17 | 180
6 | κασετίνα | όχι | όχι

Σε όλα τα παρακάτω παραδείγματα, οι περιοχές για τον υπολογισμό περιέχουν τη γραμμή #6 που αγνοείται, επειδή περιέχει κείμενο.

#### Απλή χρήση

=COUNTIFS(B2:B6;">=20")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 με τιμές μεγαλύτερες από ή ίσες με 20. Επιστρέφει 3, επειδή η πέμπτη και η έκτη γραμμή δεν ικανοποιούν το κριτήριο.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Μετρά τον αριθμό των γραμμών που περιέχουν ταυτόχρονα τιμές μεγαλύτερες από 70 στην περιοχή C2:C6 και τιμές μεγαλύτερες από ή ίσες με 20 στην περιοχή B2:B6. Επιστρέφει 2, επειδή η δεύτερη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

#### Χρήση κανονικών παραστάσεων και ένθετων συναρτήσεων

Για να δουλέψετε αυτά τα παραδείγματα όπως περιγράφτηκε, εξασφαλίστε ότι είναι επιλεγμένο το Ενεργοποίηση κανονικών εκφράσεων σε τύπους στο LibreOffice - Προτιμήσεις Εργαλεία - Επιλογές - LibreOffice Calc - Υπολογισμός.

=COUNTIFS(B2:B6;"[:alpha:]*")

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 που περιέχει μόνο αλφαβητικά σύμβολα. Επιστρέφει 1, επειδή μόνο η έκτη γραμμή πληρεί το κριτήριο.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Μετρά τον αριθμό των γραμμών στην περιοχή B2:B6 αποκλείοντας τις γραμμές με ελάχιστες και μέγιστες τιμές αυτής της περιοχής. Επιστρέφει 2, επειδή η τρίτη, η πέμπτη και η έκτη γραμμή δεν πληρούν τουλάχιστον ένα κριτήριο.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Υπολογίζει τον αριθμό των γραμμών που αντιστοιχούν σε όλα τα κελιά της περιοχής A2:A6 που ξεκινούν με "pen" και όλα τα κελιά της περιοχής B2:B6 με εξαίρεση του μεγίστου του. Επιστρέφει 1, επειδή μόνο η δεύτερη γραμμή καλύπτει όλα τα κριτήρια.

#### Αναφορά σε ένα κελί ως ένα κριτήριο

Αν χρειάζεται να αλλάξετε ένα κριτήριο εύκολα, μπορεί να θέλετε να το ορίσετε σε ένα ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στη συνθήκη της συνάρτησης COUNTIFS. Παραδείγματος χάρη, η παραπάνω συνάρτηση μπορεί να ξαναγραφτεί ως εξής:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Αν E2 = pen, η συνάρτηση επιστρέφει 1, επειδή ο σύνδεσμος στο κελί αντικαθίσταται με το περιεχόμενό του και δουλεύει όπως η παραπάνω συνάρτηση.

Σχετικά θέματα

Σελίδα βίκι COUNTIFS.

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Κατάλογος κανονικών εκφράσεων